21. Oktober 2011

Formfindung Als Grundform  dient ein symmetrisches Achteck. Aus diesem wurde auf der Unterseite in Dreieck ausgeschnitten und auf der Gegenüberliegenden Seite wieder ergänzt. Mit dieser Methode ist gewährleistet, dass die Figur sich für eine Parkettierung eignet. Parkettierung Die Grundform ist als Shape angelegt und wird durch pushMatrix untereinander und nebeneinander positioniert. Die Form wird abwechslungsweise mit unterschiedlichen Farbtönen eingefärbt. Dies ist mittels einer Hilfsvariable bewerkstelligt, die mit jedem Durchlauf um den Wert 1 erhöht wird. Durch Prüfen ob der aktuelle Stand der Zahl gerade oder ungerade ist, kann die Abwechslung geschaffen werden.

int setBackground = 200;
int setColorA = 100;
int setColorB = 50;

void setup() {
  size(600,600);
  smooth();
  strokeWeight(0);
}

void draw() {

  background(setBackground);

  int i = 0;
  int ii = 0;

  for(int x = 0; x <= width; x += 50) {
    if (i%2 == 0) {
      ii = 1;
    } else {
      ii = 0;
    }

    for(int y = 0; y <= height; y += 50) {
      pushMatrix();
        translate(x, y);
        scale(0.5);
        if (ii%2 == 0) {
          form(setColorA);
        } else {
          form(setColorB);
        }
      popMatrix();
      ii++;
    }

    i++;
  }

}

// Shortcuts
void keyPressed() {
  switch(key) {

  // Save as Image
  case 's':
    save("PARKETT.JPG");
    println("save the screen to PARKETT.JPG");
    break;

  }
}

// Form Definition
void form(int fillColor) {
  fill(fillColor);
  noStroke();
  beginShape();
    vertex(-50, -6);
    vertex(-21, -35);
    vertex(0, -65);
    vertex(21, -35);
    vertex(50, -6);
    vertex(50, 36);
    vertex(21, 65);
    vertex(0, 35);
    vertex(-21, 65);
    vertex(-50, 36);
  endShape(CLOSE);
}